{
  lib,
  config,
  pkgs,
  nvidiaGPU,
  ...
}:
with lib;
let
  desktopPackages =
    with pkgs;
    [
      grim
      slurp
      wl-clipboard
      clipman
      wf-recorder
      (nerdfonts.override { fonts = [ "JetBrainsMono" ]; })
      qt5ct
      libsForQt5.qtstyleplugin-kvantum
      font-awesome
      nordzy-cursor-theme
      jetbrains-mono
      xdg-utils
      libnotify
      adwaita-icon-theme
    ]
    ++ (
      if nvidiaGPU then
        [
          vulkan-validation-layers
          vulkan-headers
          vulkan-caps-viewer
          vulkan-extension-layer
          vulkan-tools
        ]
      else
        [ ]
    );
in
{
  imports = [
    ./sway.nix
    ./alacritty.nix
    ./swaylock.nix
    ./waybar.nix
    ./wofi.nix
    ./mako.nix
  ];

  options.desktop.enableSwayStack = mkOption {
    type = types.bool;
    default = true;
  };

  config = mkIf config.desktop.enableSwayStack {
    home.packages = desktopPackages;

    dconf = {
      enable = true;
      settings."org/gnome/desktop/interface".color-scheme = "prefer-dark";
    };

    # Theming GTK
    gtk = {
      enable = true;
      theme = {
        name = "Nordic-darker";
        package = pkgs.nordic;
      };
      cursorTheme = {
        name = "Nordzy-cursors";
        package = pkgs.nordzy-cursor-theme;
      };
    };
  };
}